os/flake.nix

{

  inputs = {
    nixpkgs.url = github:NixOS/nixpkgs/nixos-unstable;
    home-manager.url = github:nix-community/home-manager;
    pwnix = {
      inputs.nixpkgs.follows = "nixpkgs";
      url = git+https://im.badat.dev/bad/pwnix.git;
    };
    agenix.url = github:ryantm/agenix;
    nixos-hardware.url = github:NixOS/nixos-hardware;
  };

  outputs = args@{ home-manager, nixpkgs, agenix, nixos-hardware, ... }: with nixpkgs; {
  
      # Configurations for NixOS machines.
      nixosConfigurations =
        let mkUserConfig = path: {
              imports = [ home-manager.nixosModules.home-manager ];
              config = {
                home-manager.users."riley" = a: lib.pipe a [
                  (import "${path}/home.nix")
                  (x: x // {
                    imports = [ ./shared/home ];
                    isNixos = true;
                  })
                ];
              };
            };
        in {

          # Desktop system
          "strawberry" = lib.nixosSystem {
            system = "x86_64-linux";
            modules = [
              (mkUserConfig ./system/strawberry)
              agenix.nixosModules.default
              ./system/strawberry/core.nix
              ./shared/core
              ./shared/secrets.nix
            ];
            specialArgs = args;
          };

          # Thinkpad
          "lime" = lib.nixosSystem {
            system = "x86_64-linux";
            modules = [
              (mkUserConfig ./system/lime)
              agenix.nixosModules.default
	      nixos-hardware.nixosModules.lenovo-thinkpad-x390
              ./system/lime/core.nix
              ./shared/core
              ./shared/secrets.nix
            ];
            specialArgs = args;
          };

        };

      # Configurations for non-NixOS machines.
      homeConfigurations = with home-manager.lib; {
        "dev-lt-63" = homeManagerConfiguration {
          pkgs = nixpkgs.legacyPackages."x86_64-linux";
          modules = [
            ./system/dev-lt-63/home.nix
            ./shared/home
          ];
        };
      };

      overlays = {
        default = (import ./shared/overlay.nix);
      };
    
  };
  
}