{ pkgs, lib, config, ... }:

let mod = "Mod4";
    cfg = config.custom.gui.sway;

    # Generate the workspace keybinds
    genWorkspaces = { numbered, named }: with lib; (
      let nums = genAttrs (map toString (range 1 (min numbered 9))) id;
          genBindings = (num: key: {
            "${mod}+${key}"       = "workspace ${num}";
            "${mod}+Shift+${key}" = "move window to workspace ${num}";
          });
          keybinds = mapAttrsToList genBindings (nums // named);
       in mkMerge keybinds
    );

in with lib; {

  options.custom.gui.sway = with types; {
    enable = mkEnableOption "sway window manager";
    workspaces.named = mkOption {
      type = attrsOf str;
      default = {};
    };
    workspaces.numbered = mkOption {
      type = int;
      default = 5;
    };
  };

  config = mkIf (cfg.enable) {

    home.packages = with pkgs; [
      kitty
      swaylock
      wl-clipboard
      (writeScriptBin "c" ''
        ${wl-clipboard}/bin/wl-copy
      '')
      (writeScriptBin "p" ''
        ${wl-clipboard}/bin/wl-paste
      '')
    ];

    # programs.swaylock.enable = true;
    # services.swayidle.enable = true;
    programs.waybar.enable = true;

    wayland.windowManager.sway = {
      # This is all required to get it to not die.
      enable = true;
      extraSessionCommands = "export WLR_NO_HARDWARE_CURSORS=1";
      extraOptions = [ "--unsupported-gpu" ];

      config = rec {
        output."*".bg = "${../../data/wallpaper.jpg} fill";
        input."type:keyboard".xkb_options = "caps:escape";

        terminal = "kitty --single-instance";

        # Directional keys
        modifier = mod;
        fonts = {
          names = [ "Fira Code" ];
          size = 8.0;
        };

        keybindings = mkMerge [
          (genWorkspaces { inherit (cfg.workspaces) numbered named; })
          {
            "${mod}+h" = "focus left";
            "${mod}+j" = "focus down";
            "${mod}+k" = "focus up";
            "${mod}+l" = "focus right";

            "${mod}+Shift+h" = "move left";
            "${mod}+Shift+j" = "move down";
            "${mod}+Shift+k" = "move up";
            "${mod}+Shift+l" = "move right";

            "${mod}+a" = "split v";
            "${mod}+s" = "split h";
            "${mod}+f" = "fullscreen toggle";

            "${mod}+Alt+a" = "layout toggle stacking splitv";
            "${mod}+Alt+s" = "layout toggle tabbed splith";

            "${mod}+q"       = "exec ${pkgs.foot}/bin/foot";
            "${mod}+Return"  = "exec ${terminal}";
            "${mod}+Escape"  = "exec swaylock";
            "${mod}+Tab"     = "exec ${pkgs.firefox}/bin/firefox";
            "${mod}+Alt+Tab" = "exec ${pkgs.google-chrome}/bin/google-chrome-stable";

            "${mod}+Backspace" = "mode kill";
          }
        ];

        modes."kill" = {
          Backspace = "kill; mode default";
          Escape    = "mode default";
        };

        window.titlebar = true;
      };
    };

  };

}