c012f2f4ed
- [x] refactor lib into separate files, similar to NixOS/nixpkgs/lib. - [x] refactor ci to automatically generate derivations from flake outputs - [x] remove cluttered indirection statements throughout the codebase - [x] refactor hosts to allow for upcoming integration tests - [x] improve ambiguity in the existing docs - [x] add [BORS](https://bors.tech) support - [x] add initial integration test - [x] write tests documentation - [x] test lib - [x] improve version string generation, and do so automatically for pkgs/flake.nix sources Clean up the codebase as best we can in preparation for #152 and add tests. From now on, all PRs will be merged with BORS.
97 lines
1.9 KiB
Nix
97 lines
1.9 KiB
Nix
{ extern
|
|
, home
|
|
, lib
|
|
, nixos
|
|
, override
|
|
, pkgs
|
|
, self
|
|
, system
|
|
, ...
|
|
}:
|
|
let
|
|
inherit (lib) dev;
|
|
|
|
suites = import ../suites { inherit lib; };
|
|
|
|
modules =
|
|
let
|
|
core = ../profiles/core;
|
|
modOverrides = { config, overrideModulesPath, ... }:
|
|
let
|
|
overrides = import ../overrides;
|
|
inherit (overrides) modules disabledModules;
|
|
in
|
|
{
|
|
disabledModules = modules ++ disabledModules;
|
|
imports = map
|
|
(path: "${overrideModulesPath}/${path}")
|
|
modules;
|
|
};
|
|
|
|
global = {
|
|
home-manager.useGlobalPkgs = true;
|
|
home-manager.useUserPackages = true;
|
|
|
|
hardware.enableRedistributableFirmware = lib.mkDefault true;
|
|
|
|
nix.nixPath = [
|
|
"nixpkgs=${nixos}"
|
|
"nixos-config=${self}/compat/nixos"
|
|
"home-manager=${home}"
|
|
];
|
|
|
|
nixpkgs = { inherit pkgs; };
|
|
|
|
nix.registry = {
|
|
devos.flake = self;
|
|
nixos.flake = nixos;
|
|
override.flake = override;
|
|
};
|
|
|
|
system.configurationRevision = lib.mkIf (self ? rev) self.rev;
|
|
};
|
|
|
|
# Everything in `./modules/list.nix`.
|
|
flakeModules =
|
|
builtins.attrValues self.nixosModules;
|
|
|
|
in
|
|
flakeModules ++ [
|
|
core
|
|
global
|
|
modOverrides
|
|
] ++ extern.modules;
|
|
|
|
specialArgs = extern.specialArgs // { inherit suites; };
|
|
|
|
mkHostConfig = hostName:
|
|
let
|
|
local = {
|
|
require = [
|
|
"${toString ./.}/${hostName}.nix"
|
|
];
|
|
|
|
networking = { inherit hostName; };
|
|
};
|
|
in
|
|
dev.os.devosSystem {
|
|
inherit system specialArgs;
|
|
|
|
modules = modules ++ [
|
|
local
|
|
{
|
|
lib = { inherit specialArgs; };
|
|
lib.testModule = {
|
|
imports = modules;
|
|
};
|
|
}
|
|
];
|
|
};
|
|
|
|
hosts = dev.os.recImport
|
|
{
|
|
dir = ./.;
|
|
_import = mkHostConfig;
|
|
};
|
|
in
|
|
hosts
|